Inductor (Saturable)

In this topic:

Netlist Entry

Lxxxx n1 n2 modelname [N=num_turns] [LE=le] [AE=ae] [UE=ue]
n1 Node 1
n2 Node 2
modelname Model name referring to a .MODEL statement describing the core characteristics. See details below.
num_turns Number of turns on winding
le Effective path length of core in metres. Default = PATH/100. PATH is defined in .MODEL.
ae Effective area of core in metres2. Default = AREA/10000 where AREA is define in .MODEL.
ue Effective permeability of core. Overrides model parameter of the same name.

Model format - Jiles-Atherton model with hysteresis

.MODEL model_name CORE parameters

Model format - simple model without hysteresis

.MODEL model_name CORENH parameters

Jiles-Atherton Parameters

Name Description Units Default
PATH Effective path length cm 1
C Domain flexing parameter 0.2
K Domain anisotropy parameter amp.m-1 500
MS Magnetisation saturation 1E6
GAP Air gap (centimetres) cm 0
GAPM Air gap (metres) m GAP/100
A Thermal energy parameter amp.m-1 1000
AREA Effective area cm2 0.1
UE Effective permeability. Overrides GAP and GAPM if >0. See notes
AHMODE Anhysteric function selector (see notes) 0

Non-hysteresis Model Parameters

Name Description Units Default
PATH Effective path length cm 1
MS Magnetisation saturation 1E6
GAP Air gap (centimetres) cm 0
GAPM Air gap (metres) m GAP/100
A Thermal energy parameter amp.m-1 1000
AREA Effective area cm2 0.1
AHMODE Anhysteric function selector (see notes) 0

Notes on the Jiles-Atherton model

The Jiles-Atherton model is based on the theory developed by D.C. Jiles and D.L. Atherton in their 1986 paper "Theory of Ferromagnetic Hysteresis". The model has been modified to correct non-physical behaviour observed at the loop tips whereby the slope of the B-H curve reverses. This leads to non-convergence in the simulator. The modification made is that proposed by Lederer et al. (See references below). Full details of the SIMetrix implementation of this model including all the equations are provided in a technical note. This is located on the install CDROM at Docs/Magnetics/Jiles-Atherton-Model.pdf. This is also available at our web site, please visit Further Documentation for details.

The AHMODE parameter selects the equation used for the anhysteric function, that is the non-linear curve describing the saturating behaviour. When set to 0 the function is the same as that used by PSpice. When set to 1 the function is the original equation proposed by Jiles and Atherton. See the Jiles-Atherton-Model.pdf technical note for details.

If the UE parameters is specified either on the device line or in the model, an air gap value is calculated and the parameters GAP and GAPM are ignored. See the Jiles-Atherton-Model.pdf technical note for the formula used.

The parameter names and their default values for the Jiles-Atherton model are compatible with PSpice, but the netlist entry is different.

Notes on the non-hysteresis model

This is simply a reduced version of the Jiles-Atherton model with the hysteresis effects removed. The anhysteric function and the air-gap model are the same as the Jiles-Atherton model.

Implementing Transformers

This model describes only a 2 terminal inductor. A transformer can be created using a combination of controlled sources along with a single inductor. The SIMetrix schematic editor uses this method.

The schematic editor provides a means of creating transformers and this uses an arrangement of controlled sources to fabricate a non-inductive transformer. Any inductor can be added to this arrangement to create an inductive transformer. The method is simple and efficient. The following shows how a non-inductive three winding transformer can be created from simple controlled sources:

F1 0 n1 E1 1
E1 W1A W1B n1 0 1
F2 0 n1 E2 1
E2 W2A W2B n1 0 1
F3 0 n1 E3 1
E3 W3A W3B n1 0 1

Connecting an inductor between n1 and 0 in the above provides the inductive behaviour. This is in fact how the SIMetrix schematic editor creates non-linear transformers.

Note that you cannot use the mutual inductor device with the saturable inductor.

Plotting B-H curves

Both models can be enabled to output values for flux density in Tesla and magnetising force in A.m-1. To do this, add the following line to the netlist:

.KEEP Lxxx#B Lxxx#H

Replace Lxxx with the reference for the inductor. (e.g. L23 etc.). You will find vectors with the names Lxxx#B Lxxx#H available for plotting in the waveform viewer.

References

  1. Theory of Ferromagnetic Hysteresis, DC.Jiles, D.L. Atherton, Journal of Magnetism and Magnetic Materials, 1986 p48-60.
  2. On the Parameter Identification and Application of the Jiles-Atherton Hysteresis Model for Numerical Modelling of Measured Characteristics, D Lederer, H Igarashi, A Kost and T Honma, IEEE Transactions on Magnetics, Vol. 35, No. 3, May 1999